CMD – aktualizacja baz wirusów Aviry przy użyciu konsoli.
Strona główna CMD C++ Hardware HTML i javascript Java Software SQL

CMD – aktualizacja baz wirusów Aviry przy użyciu konsoli.

Dodano: 2012-03-16

Program Avira dzięki ciągłemu rozwojowi i powstawaniu nowych ciekawych narzędzi staje się coraz bardziej interesującym programem antywirusowym dla administratorów systemowych.

Konsolowa instalacja Aviry jest łatwa w konfiguracji jak i instalacji.

Avira wypuściła program fusebundle zarówno dla systemów Windows jak Linux, który umożliwia pobranie aktualnych sygnatur wirusów z linii komend. Dzięki temu narzędziu możemy pobrać bazę wirusów na serwer lokalny FTP jeden raz, aby następnie rozesłać je do poszczególnych jednostek sieci LAN.

Dzięki fusebundle możemy też stworzyć skrypt, który umożliwia pobranie automatyczne najbardziej aktualnej bazy wirusów oraz ich instalację.

Program fusebundle pobiera najbardziej aktualne pliki bibliotek w postaci archiwum *.zip, w przypadku istnienia już wersji archiwum wykonuje tylko jego konieczną aktualizację.

Poniżej znajduje się skrypt, który za pomocą fusebundle pobiera aktualną wersję bibliotek do folderu install_avira, po wykonaniu tej operacji za pomocą programu 7zip (musisz go mieć zainstalowanego :) wykonuje rozpakowanie archiwum. Jeżeli plik z nowymi sygnaturami jest różny wielkościowo od pliku po uruchomieniu programu aktualizacyjnego, następuje rozpakowanie archiwum. Skrypt powinien znajdować się w folderze programu konsolowego Avira wraz z fusebundle.

Pojedyncze kliknięcie zaznaczenie, podwójne wydrukowanie kodu.

@echo off
setlocal EnableDelayedExpansion

@echo Skrypt pobiera najnowsze biblioteki programu Avira, za pomoca narzedzia Avira Fusebundle Generator.
@echo Nastepnie instaluje je dla programu konsolowego Avira.
@echo Program Avira Fusebundle Generator powinien znajdowac sie w folderze programu konsolowego Avira, skryp nalezy tez skopiwac do tegoz folderu a nastepnie uruchomic (w innym wypadku zedytuj sciezki).
@echo.

set size=0
if not exist install_avira\vdf_fusebundle.zip GOTO UPDATE

for %%a in ("install_avira\vdf_fusebundle.zip") DO (
	set size=%%~za
	@echo Rozmiar pliku przed aktualizacja: !size!
)

:UPDATE
@echo Pobieranie aktualizacji...
fusebundle /i install_avira /t temp_avira
if [%errorlevel%] NEQ [0] GOTO ERROR

for %%a in ("install_avira\vdf_fusebundle.zip") DO (
	@echo Rozmiar pliku po aktualizacji: %%~za
	if [!size!] NEQ [%%~za]	(
		@echo Instalacja archiwum...
		7z e -y install_avira\vdf_fusebundle.zip
	) ELSE (
		@echo Pliki indentyczne rozmiarami.
	)

)
GOTO END

:ERROR
@echo !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
@echo Aktualizacja sie nie powiodla!!!


:END

Testowane w Windows 7